Figure oneoverx.asy
import graph;
size(200,IgnoreAspect);
real f(real x) {return 1/x;};
bool3 branch(real x)
{
static int lastsign=0;
if(x == 0) return false;
int sign=sgn(x);
bool b=lastsign == 0 || sign == lastsign;
lastsign=sign;
return b ? true : default;
}
draw(graph(f,-1,1,branch));
axes("$x$","$y$",red);
Figure orthocenter.asy
import geometry;
import math;
size(7cm,0);
real theta=degrees(asin(0.5/sqrt(7)));
pair B=(0,sqrt(7));
pair A=B+2sqrt(3)*dir(270-theta);
pair C=A+sqrt(21);
pair O=0;
pair Ap=extension(A,O,B,C);
pair Bp=extension(B,O,C,A);
pair Cp=extension(C,O,A,B);
perpendicular(Ap,NE,Ap--O,blue);
perpendicular(Bp,NE,Bp--C,blue);
perpendicular(Cp,NE,Cp--O,blue);
draw(A--B--C--cycle);
currentpen=black;
draw("1",A--O,-0.25*I*dir(A--O));
draw(O--Ap);
draw("$\sqrt{7}$",B--O,LeftSide);
draw(O--Bp);
draw("4",C--O);
draw(O--Cp);
dot("$O$",O,1.5*dir(B--Bp,Cp--C),red);
dot("$A$",A,1.5*dir(C--A,B--A),red);
dot("$B$",B,NW,red);
dot("$C$",C,dir(A--C,B--C),red);
dot("$A'$",Ap,dir(A--Ap),red);
dot("$B'$",Bp,dir(B--Bp),red);
dot("$C'$",Cp,dir(C--Cp),red);
label(graphic("piicon.eps","width=2.5cm"),Ap,5ENE,red);
Figure phase.asy
import graph;
size(8cm,6cm,IgnoreAspect);
pair S0=(4,0.2);
pair S1=(2,3);
pair S8=(0.5,0);
xaxis("$S$");
yaxis(Label("$I$",0.5));
draw(S0{curl 0}..tension 1.5..S1{W}..tension 1.5..{curl 0}S8,Arrow(Fill,0.4));
draw((S1.x,0)..S1,dashed);
draw((0,S1.y)..S1,dotted);
labelx("$\frac{\gamma}{\beta}$",S1.x);
labelx("$S_\infty$",S8.x);
labely("$I_{\max}$",S1.y);
Figure polararea.asy
import math;
import graph;
size(0,150);
real f(real t) {return 5+cos(10*t);}
xaxis("$x$");
yaxis("$y$");
real theta1=pi/8;
real theta2=pi/3;
path k=graph(f,theta1,theta2,operator ..);
real rmin=min(k).y;
real rmax=max(k).y;
draw((0,0)--rmax*expi(theta1),dotted);
draw((0,0)--rmax*expi(theta2),dotted);
path g=polargraph(f,theta1,theta2,operator ..);
path h=(0,0)--g--cycle;
fill(h,lightgray);
draw(h);
real thetamin=3*pi/10;
real thetamax=2*pi/10;
pair zmin=polar(f(thetamin),thetamin);
pair zmax=polar(f(thetamax),thetamax);
draw((0,0)--zmin,dotted+red);
draw((0,0)--zmax,dotted+blue);
draw("$\theta_*$",arc((0,0),0.5*rmin,0,degrees(thetamin)),red+fontsize(10pt),
PenMargins);
draw("$\theta^*$",arc((0,0),0.5*rmax,0,degrees(thetamax)),blue+fontsize(10pt),
PenMargins);
draw(arc((0,0),rmin,degrees(theta1),degrees(theta2)),red,PenMargins);
draw(arc((0,0),rmax,degrees(theta1),degrees(theta2)),blue,PenMargins);
Figure polarcircle.asy
import math;
import graph;
size(0,100);
real f(real t) {return 2*cos(t);}
pair F(real x) {return (x,f(x));}
draw(polargraph(f,0,pi,operator ..));
defaultpen(fontsize(10pt));
xaxis("$x$");
yaxis("$y$");
real theta=radians(50);
real r=f(theta);
draw("$\theta$",arc((0,0),0.5,0,degrees(theta)),red,Arrow,PenMargins);
pair z=polar(r,theta);
draw(z--(z.x,0),dotted+red);
draw((0,0)--(z.x,0),dotted+red);
label("$r\cos\theta$",(0.5*z.x,0),0.5*S,red);
label("$r\sin\theta$",(z.x,0.5*z.y),0.5*E,red);
dot("$(x,y)$",z,N);
draw("r",(0,0)--z,0.5*unit(z)*I,blue,Arrow,DotMargin);
dot("$(a,0)$",(1,0),NE);
dot("$(2a,0)$",(2,0),NE);